Pig DIFF 函数

  • DIFF 函数

    Pig-Latin DIFF() 函数用于比较元组中的两个包(字段)。它以元组的两个字段作为输入并进行匹配。如果它们匹配,它将返回一个空bag。如果它们不匹配,它将查找在一个字段(bag)中存在而在另一字段(bag)中没有的元素,并通过将它们包装在bag中来返回这些元素。
    句法
    下面给出了DIFF() 函数的语法。
    
    grunt> DIFF (expression, expression)
    
    例子
    通常,DIFF() 函数比较一个元组中的两个包。下面给出了它的示例,在这里我们创建两个关系,将它们组合在一起,并计算它们之间的差。
    假设我们在HDFS目录/pig_data/中有两个文件,分别是emp_sales.txt和emp_bonus.txt,如下所示。该emp_sales.txt包含销售部门的员工的细节和emp_bonus.txt包含员工详细谁得到奖金。
    emp_sales.txt
    
    1,Robin,22,25000,sales 
    2,BOB,23,30000,sales 
    3,Maya,23,25000,sales 
    4,Sara,25,40000,sales 
    5,David,23,45000,sales 
    6,Maggy,22,35000,sales
    
    emp_bonus.txt
    
    1,Robin,22,25000,sales 
    2,Jaya,23,20000,admin 
    3,Maya,23,25000,sales 
    4,Alia,25,50000,admin 
    5,David,23,45000,sales 
    6,Omar,30,30000,admin
    
    我们已经将这些文件加载​​到Pig中,它们的关系名称分别为emp_sales和emp_bonus。
    
    grunt> emp_sales = LOAD 'hdfs://localhost:9000/pig_data/emp_sales.txt' USING PigStorage(',')
       as (sno:int, name:chararray, age:int, salary:int, dept:chararray);
       
    grunt> emp_bonus = LOAD 'hdfs://localhost:9000/pig_data/emp_bonus.txt' USING PigStorage(',')
       as (sno:int, name:chararray, age:int, salary:int, dept:chararray);
    
    如下所示,使用COGROUP运算符使用键sno对emp_sales和emp_bonus关系的记录/元组进行分组。
    
    grunt> cogroup_data = COGROUP emp_sales by sno, emp_bonus by sno;
    
    如下所示,使用DUMP运算符验证关系cogroup_data。
    
    grunt> Dump cogroup_data;
      
    (1,{(1,Robin,22,25000,sales)},{(1,Robin,22,25000,sales)}) 
    (2,{(2,BOB,23,30000,sales)},{(2,Jaya,23,20000,admin)}) 
    (3,{(3,Maya,23,25000,sales)},{(3,Maya,23,25000,sales)}) 
    (4,{(4,Sara,25,40000,sales)},{(4,Alia,25,50000,admin)}) 
    (5,{(5,David,23,45000,sales)},{(5,David,23,45000,sales)}) 
    (6,{(6,Maggy,22,35000,sales)},{(6,Omar,30,30000,admin)})
    
  • 计算两个关系之间的差异

    现在让我们使用DIFF() 函数计算两个关系之间的差异,并将其存储在关系diff_data中,如下所示。
    
    grunt> diff_data = FOREACH cogroup_data GENERATE DIFF(emp_sales,emp_bonus);
    
    验证
    如下所示,使用DUMP运算符验证关系diff_data。
    
    grunt> Dump diff_data;
       
    ({}) 
    ({(2,BOB,23,30000,sales),(2,Jaya,23,20000,admin)}) 
    ({}) 
    ({(4,Sara,25,40000,sales),(4,Alia,25,50000,admin)}) 
    ({}) 
    ({(6,Maggy,22,35000,sales),(6,Omar,30,30000,admin)})
    
    该diff_data关系将有一个空的元组如果记录emp_bonus和emp_sales匹配。在其他情况下,它将保存两个关系中的元组(不同的元组)。例如,如果您认为sno为1的记录,则将在两个关系中发现它们相同((1,Robin,22,25000,sales),(1,Robin,22,25000,sales))。因此,在diff_data关系中(这是DIFF() 函数的结果),您将获得sno 1的空元组。