VB.Net 异常处理



  • 异常处理

    异常是在程序执行期间出现的问题。异常是对程序运行时出现的异常情况的响应,例如尝试除以零。异常提供了一种将控制权从程序的一部分转移到另一部分的方法。VB.Net异常处理基于四个关键字-Try,Catch,Finally和Throw
    • Try-尝试块标识将为其激活特定异常的代码块。其次是一个或多个Catch块。
    • Catch-程序在要处理问题的程序中的某个位置捕获带有异常处理程序的异常。Catch关键字指示捕获异常。
    • Finally-最终块用于执行给定的一组语句,无论是否引发异常。例如,如果打开文件,则无论是否引发异常,都必须关闭该文件。
    • Throw-问题出现时,程序将引发异常。这是使用Throw关键字完成的。
    句法
    假设一个块将引发异常,则一种方法使用Try和Catch关键字的组合来捕获异常。在可能产生异常的代码周围放置了一个 Try/Catch块。Try/Catch 块中的代码称为受保护的代码,使用 Try/Catch 的语法如下所示-
    
    Try
       [ tryStatements ]
       [ Exit Try ]
    [ Catch [ exception [ As type ] ] [ When expression ]
       [ catchStatements ]
       [ Exit Try ] ]
    [ Catch ... ]
    [ Finally
       [ finallyStatements ] ]
    End Try
    
    
    您可以列出多个catch语句以捕获不同类型的异常,以防在不同情况下try块引发多个异常。
  • .NET Framework中的 Exception 类

    在.Net Framework 中,异常由类表示。.Net Framework中的异常类主要是直接或间接从System.Exception类派生的。从System.Exception类派生的某些异常类是System.ApplicationExceptionSystem.SystemException类。
    System.ApplicationException 类支持异常,由应用程序产生的。因此,程序员定义的异常应从此类派生。
    System.SystemException类是所有预定义的系统异常的基类。
    下表提供了一些从Sytem.SystemException类派生的预定义异常类-
    异常类别 描述
    System.IO.IOException 处理I/O错误。
    System.IndexOutOfRangeException 处理方法引用数组索引超出范围时产生的错误。
    System.ArrayTypeMismatchException 处理类型与数组类型不匹配时生成的错误。
    System.NullReferenceException 处理由于引用空对象而产生的错误。
    System.DivideByZeroException 处理因除以零而产生的错误。
    System.InvalidCastException 处理类型转换期间生成的错误。
    System.OutOfMemoryException 处理由于可用内存不足而产生的错误。
    System.StackOverflowException 处理由堆栈溢出产生的错误。
  • 处理异常

    VB.Net以try和catch块的形式为异常处理问题提供了结构化的解决方案。使用这些块,核心程序语句与错误处理语句分离。
    这些错误处理块是使用Try,Catch 和 Final 关键字实现的。以下是发生除以零的条件时引发异常的示例-
    
    Module exceptionProg
       Sub division(ByVal num1 As Integer, ByVal num2 As Integer)
          Dim result As Integer
          Try
             result = num1 \ num2
          Catch e As DivideByZeroException
             Console.WriteLine("Exception caught: {0}", e)
          Finally
             Console.WriteLine("Result: {0}", result)
          End Try
       End Sub
       Sub Main()
          division(25, 0)
          Console.ReadKey()
      End Sub
    End Module
    
    
    尝试一下
    编译并执行上述代码后,将产生以下结果-
    
    Exception caught: System.DivideByZeroException: Attempted to divide by zero.
    at exceptionProg.division (System.Int32 num1, System.Int32 num2) [0x00002] in <261bd940dda94fed99df23f4aaa942ca>:0 
    Result: 0
    
    
  • 建用户定义的异常

    您也可以定义自己的异常。用户定义的异常类是从ApplicationException类派生的。以下示例演示了这一点-
    
    Module exceptionProg
       Public Class TempIsZeroException : Inherits ApplicationException
          Public Sub New(ByVal message As String)
             MyBase.New(message)
          End Sub
       End Class
       Public Class Temperature
          Dim temperature As Integer = 0
          Sub showTemp()
             If (temperature = 0) Then
                Throw (New TempIsZeroException("Zero Temperature found"))
             Else
                Console.WriteLine("Temperature: {0}", temperature)
             End If
          End Sub
       End Class
       Sub Main()
          Dim temp As Temperature = New Temperature()
          Try
             temp.showTemp()
          Catch e As TempIsZeroException
             Console.WriteLine("TempIsZeroException: {0}", e.Message)
          End Try
          Console.ReadKey()
       End Sub
    End Module
    
    
    尝试一下
    编译并执行上述代码后,将产生以下结果-
    
    TempIsZeroException: Zero Temperature found
    
    
  • 抛出对象

    如果对象是直接或间接从System.Exception类派生的,则可以抛出该对象。
    您可以在catch块中使用throw语句将当前对象抛出为-
    
    Throw [ expression ]
    
    
    以下程序演示了这一点-
    
    Module exceptionProg
       Sub Main()
          Try
             Throw New ApplicationException("A custom exception _ is being thrown here...")
          Catch e As Exception
             Console.WriteLine(e.Message)
          Finally
             Console.WriteLine("Now inside the Finally Block")
          End Try
          Console.ReadKey()
       End Sub
    End Module
    
    
    尝试一下
    编译并执行上述代码后,将产生以下结果-
    
    A custom exception _ is being thrown here...
    Now inside the Finally Block